#-------------------------------------------------
#
# Project created by QtCreator 2012-10-24T09:22:29
#
#-------------------------------------------------

QT       += core

QT       -= gui

TARGET = test
CONFIG   += console
CONFIG   -= app_bundle

TEMPLATE = app

INCLUDEPATH += . .. \
               c:/odb/libodb \
               c:/odb/libodb-qt \
               c:/odb/libodb-sqlite \
               c:/odb/libodb-sqlite/etc/sqlite

SOURCES += \
    driver.cxx

HEADERS += employee.hxx database.hxx

# List of header files that should be compiled with the ODB compiler.
#
ODB_FILES += employee.hxx

# ODB compiler flags.
#
ODB_FLAGS = --database sqlite --profile qt --generate-schema --generate-query --generate-session

# Select the database we are going to use.
#
DEFINES += DATABASE_SQLITE

# Suppress unknown pragmas GCC warnings.
#
QMAKE_CXXFLAGS_WARN_ON += -wd4068

# Link to the ODB runtime libraries.
#
LIBS += -lodb-sqlite.lib
LIBS += -lodb-qt.lib
LIBS += -lodb.lib

# ODB compilation rules. Normally you don't need to change anything here.
#
for(dir, QMAKE_INCDIR_QT) {
  ODB_FLAGS += -I$${dir}
}

odb.name = odb ${QMAKE_FILE_IN}
odb.input = ODB_FILES
odb.output = ${QMAKE_FILE_BASE}-odb.cxx
odb.commands = odb $$ODB_FLAGS ${QMAKE_FILE_IN}
odb.depends = ${ODB_FILES}
odb.variable_out = SOURCES
odb.clean = ${QMAKE_FILE_BASE}-odb.cxx ${QMAKE_FILE_BASE}-odb.hxx ${QMAKE_FILE_BASE}-odb.ixx ${QMAKE_FILE_BASE}.sql
QMAKE_EXTRA_COMPILERS += odb

odbh.name = odb ${QMAKE_FILE_IN}
odbh.input = ODB_FILES
odbh.output = ${QMAKE_FILE_BASE}-odb.hxx
odbh.commands = rem
odbh.CONFIG = no_link
odbh.depends = ${QMAKE_FILE_BASE}-odb.cxx
QMAKE_EXTRA_COMPILERS += odbh